home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib11.dsk / COMPACT CROUT.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  40 lines
  1. 10  REM  ***************************
  2. 20  REM  *                         *
  3. 30  REM  *  COMPACT CROUT UTILITY  *
  4. 40  REM  *  BY SIDNEY A. POWERS    *
  5. 50  REM  *  DUNCANVILLE, TEXAS     *
  6. 60  REM  *  75137                  *
  7. 70  REM  *                         *
  8. 80  REM  *  THIS ONE LINE PROGRAM  *
  9. 90  REM  *  SOLVES SIMULTANEOUS    *
  10. 100  REM *  LINEAR EQUATIONS       *
  11. 110  REM *  (C) 1982 MICRO-SPARC   *
  12. 120  REM ***************************
  13. 130  DIM A(5,6)
  14. 140  DATA   1,1,1,1
  15. 150  DATA   5,1,2,1
  16. 160  DATA   1,-6,9,-1
  17. 170  DATA   3,2,1,-1
  18. 180  DATA   100,220,190,150
  19. 190 N = 4
  20. 200 P = N +1
  21. 210  FOR I = 1 TO N
  22. 220  FOR J = 1 TO N
  23. 230  READ A(I,J)
  24. 240  NEXT J,I
  25. 250  FOR I = 1 TO N
  26. 260  READ A(I,P)
  27. 270  NEXT I
  28. 280  PRINT "INPUT MATRIX "
  29. 290  FOR I = 1 TO 4
  30. 300  PRINT "A(";I;",J) = ";
  31. 310  FOR J = 1 TO 4
  32. 320  PRINT A(I,J);";";
  33. 330  NEXT J
  34. 340  PRINT A(I,5); CHR$(13)
  35. 350  NEXT I
  36. 360  PRINT "SOLUTION"
  37. 370  FOR J = 2 TO P:A(1,J) = A(1,J)/A(1,1): NEXT J: FOR J = 2 TO N:K = J -1: FOR I = J TO N: FOR L = 1 TO K:A(I,J) = A(I,J) -A(L,J) *A(I,L):A(J,I +1) = A(J,I +1) -A(L,I +1) *A(J,L): NEXT L:A(J,I +1) = A(J,I +1)/A(J,J): NEXT I,J: FOR J = 2 TO N:K = P -J:M = J -1: FOR L = 1 TO M:Q = P -L:A(K,P) = A(K,P) -A(K,Q) *A(Q,P): NEXT L,J
  38. 380  FOR I = 1 TO N
  39. 390  PRINT "X(";I;") = ";A(I,P)
  40. 400  NEXT